Repositorio IRC

Repositorio de scripts de irc.terrachat.cl desde los canales #TRAFFIC y #LATINWAREZ.
;##########################################################################
;##########################################################################
;##    
;##    AutoQ, formerly known as rarQ
;##
;##    A small and simple auto get script for !rar and regular servers
;##    by Moros
;##
;##  Does not work with custom color schemes
;## 
;##  This build works with the new request format !nick !rar folderpath
;##
;##  Right click in a channel to open a Q
;##  Paste !nick !rar paths and/or !nick filenames into the text line of the Q
;##    If pasting one line need to hit enter
;##    Paste multiple lines no need to hit enter
;##  Double click first line of server to start the Q
;##  Right click in the Q for more options 
;##  Close the Q with lines remaining and it saves
;##  Open the Q and it loads what was saved
;##  On Get Fail it will request the same again  
;## 
;##  build 1557154050 2019.05.06
;##########################################################################
;##########################################################################


menu channel {
  -
  AutoQ: {
    var %Qwin = @Q/ $+ $active, %Qfile = $remove($qt($mircdir $+ AutoQ\ $+ $active $+ .txt),@Q/)
    if (!$window(%Qwin)) {
      window -Deik0lv %Qwin 0 0 500 350 
      if ($isfile(%Qfile)) {
        loadbuf %Qwin %Qfile
        window -b $active
      }
    }
    else { window -ar %Qwin }
  }
}

menu nicklist {
  -
  $iif(($me !isin $snicks),AutoQ)
  .Get Listfile: {
    var %i = 1
    while (%i <= $snick($chan,0)) {
      if (($window(@OS.Buffer)) && ($timer(SDbuff))) { aline @OS.Buffer scid $cid msg $chan $+(@,$snick($chan,%i))  ::4,0Auto12,0Q1,0:: }
      else { msg $chan $+(@,$snick($chan,%i))  ::4,0Auto12,0Q1,0:: }
      inc %i 
    }
  }
  .Que Status: {
    var %i = 1
    while (%i <= $snick($chan,0)) {
      if (($window(@OS.Buffer)) && ($timer(SDbuff))) { aline @OS.Buffer scid $cid msg $chan $+($snick($chan,%i),-que) }
      else { msg $chan +($snick($chan,%i),-que) }
      inc %i 
    }
  }
}

menu @Q/* {
  dclick: {
    if ($active isin %OT.Q) { %OT.Q = $remove(%OT.Q,$active) }
    request
  }
  .$iif(($active !isin %OT.Q),Pause AutoQ): { set -e %OT.Q %OT.Q $active }
  $iif(($line($active,0)),Edit)
  .$iif((($line($active,0)) && ($sline($active,0) < $line($active,0)) || (!$sline($active,0))), Select all, $style(2) Select all): {
    var %i = 1
    while (%i <= $line($active,0)) {
      sline -a $active %i
      inc %i
    }
  }
  .$iif((($line($active,0)) && ($sline($active,0))), Cut, $style(2) Cut): { clipboard $null | clip | remlines }
  .$iif((($line($active,0)) && ($sline($active,0))), Copy, $style(2) Copy): { clipboard $null | clip }
  .$iif((($line($active,0)) && ($sline($active,0))), Delete, $style(2) Delete): { remlines }
  $iif(($sline($active,0)),Selection)
  .Request: {
    if ($active isin %OT.Q) { %OT.Q = $remove(%OT.Q,$active) }
    request
  }
  .Reset: reset
  .Deselect: clearsel
  Window
  .$iif(($line($active,0)), Clear, $style(2) Clear): { clear $active | savebuf $active $remove($qt($mircdir $+ AutoQ\ $+ $active $+ .txt),@Q/) }
  .$iif(($line($active,0)),Save As..., $style(2) Save As...) { savebuf $active $+(",$$sfile($remove($qt($mircdir $+ AutoQ\ $+ $active $+ .txt),@Q/),Select file,Save As),$qt($mircdir $+ AutoQ\)") }
  .Close: { closeclean $active | close -@ $active }
}

on *:close:@Q/*: { closeclean $target }

on *:load; {
  writeini mirc.ini text accept $addtok($readini(mirc.ini,text,accept),*.mp3,44)
  writeini mirc.ini text accept $addtok($readini(mirc.ini,text,accept),*.rar,44)
}

on *:unload: {
  close -@Q/*
  unset %OT.*
  .echo -q $findfile($mircdir $+ AutoQ,*,0,remove $qt($1-))
  .rmdir $qt($mircdir $+ AutoQ)
}

on *:filercvd:*: {
  var %i = $window(@Q/*,0)
  while (%i >= 1) {
    var %t = $line($window(@Q/*,%i),0)
    while (%t >= 1) {
      tokenize 32 $line($window(@Q/*,%i),%t)
      var %serv = $1
      if (($trunc($nopath($filename)) == $trunc($2-)) || ($left($trunc($nopath($filename)),-4) == $nopath($left($trunc($3-),-1)))) {
        var %win = $window(@Q/*,%i)
        dline %win %t
        savebuf %win $remove($qt($mircdir $+ AutoQ\ $+ %win $+ .txt),@Q/)
        var %n = 1
        while (%n <= $line(%win,0)) {
          if (%win !isin %OT.Q) {
            if (($1 isin $line(%win,%n)) && ($line(%win,%n).color == 1)) {
              if (($window(@OS.Buffer)) && ($timer(SDbuff))) { aline @OS.Buffer scid $cid msg $remove(%win,@Q/) $line(%win,%n) }
              else { msg $remove(%win,@Q/) $line(%win,%n) }
              cline 15 %win %n
              return
            }
          }
          inc %n
        }
      }
      dec %t
    }
    dec %i
  }
}

on *:getfail:*.*: {
  var %i = $window(@Q/*,0)
  while (%i >= 1) {
    var %t = $line($window(@Q/*,%i),0)
    while (%t >= 1) {
      tokenize 32 $line($window(@Q/*,%i),%t)
      var %serv = $1
      if (($trunc($nopath($filename)) == $trunc($2-)) || ($left($trunc($nopath($filename)),-4) == $nopath($left($trunc($3-),-1)))) {
        var %win = $window(@Q/*,%i)
        if (($window(@OS.Buffer)) && ($timer(SDbuff))) { aline @OS.Buffer scid $cid msg $remove(%win,@Q/) $line(%win,%t) } 
        else { msg $remove(%win,@Q/) $line(%win,%t) }
      }
      dec %t
    }
    dec %i
  }
}

on *:input:@Q/*: {
  if (($left($1-,1) == !) && ($2 != !rar)) {
    var %i = 1, %accept = $remove($readini($+(",$mircdir\mirc.ini,"),text,accept),*)
    while (%i <= $numtok(%accept,44)) {
      if ($gettok(%accept,%i,44) isin $1-) {
        var %fl = $fline($active,$1 $+ *,0)
        if (%fl == 0) { aline -n $active $left($1-,$calc($pos($1-,$gettok(%accept,%i,44),1) + $len($gettok(%accept,%i,44)))) }
        else { iline -n $active $calc($fline($active,$1 $+ *,%fl) + 1) $left($1-,$calc($pos($1-,$gettok(%accept,%i,44),1) + $len($gettok(%accept,%i,44)))) }
      }
      inc %i
    }
  }
  if (($2 == !rar) && ($3 != $null)) { aline -n $1-  }
  window -b $target
  savebuf $active $remove($qt($mircdir $+ AutoQ\ $+ $active $+ .txt),@Q/)
}

on *:keydown:@Q/*:46: { remlines }

alias -l clip {
  var %i = 1, %clip
  while (%i <= $sline($active,0)) {
    clipboard -an $sline($active,%i)
    inc %i
  }
}

alias -l closeclean {
  var %Qfile = $remove($qt($mircdir $+ AutoQ\ $+ $1 $+ .txt),@Q/)
  if ($line($1,0) > 0) {
    if ($1 isin %OT.Q) { %OT.Q = $remove(%OT.Q,$1) }
    savebuf $1 %Qfile
  }
  elseif ($isfile(%Qfile)) { .remove %Qfile }
}

alias -l request {
  var %i = 1
  while (%i <= $sline($active,0)) {
    if (($window(@OS.Buffer)) && ($timer(SDbuff))) { aline @OS.Buffer scid $cid msg $remove($active,@Q/) $sline($active,%i) }
    else { msg $remove($active,@Q/) $sline($active,%i) }
    cline 15 $sline($active,%i).ln
    inc %i 
  }
}

alias -l clearsel { 
  aline -s $active $chr(160)
  .timer -m 1 10 dline $active $line($active,0)
}

alias -l remlines {
  var %i = $sline($active,0)
  while (%i >= 1) {
    dline $active $sline($active,%i).ln
    dec %i
  }
  window -b $active
  savebuf $active $remove($qt($mircdir $+ AutoQ\ $+ $active $+ .txt),@Q/)
}

alias -l reset {
  var %i = 1, %t = $sline($active,0)
  while (%i <= %t) {
    cline 1 $sline($active,%i).ln
    inc %i
  }
}

alias -l trunc { return $remove($1-,_,$chr(32)) }
Explorando: ./mrc

Vista previa de: AutoQ.mrc
