Repositorio IRC

Repositorio de scripts de irc.terrachat.cl desde los canales #TRAFFIC y #LATINWAREZ.
on *:start:hmake xdccv 50

alias xdccv if (!$dialog(xdccv)) dialog -m xdccv xdccv
alias addpacket {
  ; /addpacket [nick] [packet N] [line]
  if (!$3) halt
  hadd xdccv $+($1,_,$remove($2,$chr(35))) $3-
  if ($dialog(xdccv)) && (!$didwm(xdccv,27,$1,1)) did -a xdccv 27 $1
}
menu nicklist {
  XDCC LIST:ctcp $* xdcc list
}
alias xpack {

  ; this determines if the text is a text line or an xdcc pack
  ; you can add your own, you better know how to script though...
  ; if you find an xdcc match, you HAVE to 'return packN [text]'

  tokenize 32 $strip($1-)

  ; iroffer
  ; #1 14x [ 50M] a_file.zip
  ;
  var %format = #?* [*?*] *
  if (%format iswm $1-) {
    if (*x iswm $2) tokenize 32 $1 $3-
    if ([*] iswm $2-3) tokenize 32 $1 $2 $+ $3-
    var %pack = $regex($1,^(#|)[0-9]+$)
    if (!%pack) return 0 
    return $remove($1,$chr(35)) $3-
  }

  ; eirc xdcc
  ; #1 arg.exe :: description
  ;
  var %format = #?* *?* :: *?*
  if (%format iswm $1-) {
    var %pack = $regex($1,^(#|)[0-9]+$)
    if (!%pack) return 0 
    return $remove($1,$chr(35)) $2-
  }

  ; ? xdcc (if you know what it's from tell me, polaris maybe?)
  ; [#13] (0x|639.8Mb) - blahhh.iso
  ;
  var %format = [#*] (*x|*b) - *
  if (%format iswm $1-) {
    var %pack = $regex($1,^\[(#|)[0-9]+\]$)  
    if (!%pack) return 0
    return $remove($1,[,],$chr(35)) $4-
  }
}
dialog xdccv {
  title "Visor XDCC"
  size -1 -1 631 370
  box "Servidores", 1, 5 5 160 325
  button "Aceptar", 2, 471 338 75 25, ok
  button "Cancelar", 3, 550 338 75 25, cancel
  box "Paquetes", 4, 169 5 455 325
  list 27, 11 20 147 303, size sort
  list 28, 176 20 439 302, size sort hsbar
  menu "Archivo", 5
  item "Abrir...", 34, 5
  item "Abrir nuevo...", 8, 5
  item "Guardar como...", 9, 5
  item break, 10, 5
  item "Salir", 11, 5
  menu "Servidores", 6
  item "Vaciar lista", 12, 6
  item "Eliminar seleccionado", 13, 6
  item "Solicitar 'XDCC LIST' ", 14, 6
  menu "Paquetes", 29
  item "Solicitar descarga", 30, 29
  item break, 31, 29
  item "Copiar seleccionado", 32, 29
  item "Copiar lista", 33, 29

  menu "Configuración", 7
  item "Mostrar en la barra de tareas", 17, 7
  menu "Acerca de", 22
  item "Ayuda...", 23, 22
  item break, 24, 22
  item "Acerca de...", 25, 22

  button "Buscar...", 35, 5 338 75 25
}
on *:dialog:xdccv:sclick:35:xdccs
on *:dialog:xdccv:menu:32:clipboard $$did($dname,28).seltext
on *:dialog:xdccv:menu:33:clipboard $$did($dname,28,1) $+ $crlf | var %a = 2 | while ($did($dname,28,%a)) { clipboard -a $ifmatch $+ $crlf | inc %a }
on *:dialog:xdccv:menu:8:hdel -w xdccv * | hload xdccv " $+ $$sfile(*.xdc,Select file) $+ " | dialog -x $dname | xdccv
on *:dialog:xdccv:menu:34:hload xdccv " $+ $$sfile(*.xdc,Select file) $+ " | dialog -x $dname | xdccv
on *:dialog:xdccv:menu:9:hsave -o xdccv " $+ $$sfile(xdcc-list.xdc,Select file,Save) $+ "
on *:dialog:xdccv:menu:12:hdel -w xdccv * | did -r $dname 27,28
on *:dialog:xdccv:menu:11:dialog -x $dname
on *:dialog:xdccv:menu:23:help
on *:dialog:xdccv:menu:25:return $input(Buscador XDCC.(v.b.2025) $crlf $+ by TRAFFIC WAREZ GROUP @TWGChat $crlf $+ $crlf Agradecemos : $crlf #TRAFFIC - #LatinWarez - irc.terrachat.cl,124)
on *:dialog:xdccv:menu:17:var %dname = $dname | dialog -x %dname | dialog -md %dname %dname
on *:dialog:xdccv:dclick:28:var %msg = $$did($dname,27).seltext xdcc send $+($chr(35),$calc($gettok($gettok($$did($dname,28).seltext,1,32),1,46))) | ctcp %msg | if ($network == DALnet) /dccallow $+(+,$$did($dname,27))
on *:dialog:xdccv:menu:30:var %msg = $$did($dname,27).seltext xdcc send $+($chr(35),$calc($gettok($gettok($$did($dname,28).seltext,1,32),1,46))) | ctcp %msg | if ($network == DALnet) /dccallow $+(+,$$did($dname,27))
on *:dialog:xdccv:menu:14:var %msg = $$did($dname,27).seltext xdcc list | ctcp %msg
on *:dialog:xdccv:menu:13:var %nick = $$did($dname,27).seltext | did -d $dname 27 $did($dname,27).sel | hdel -w xdccv $+(%nick,_*)
on *:dialog:xdccv:init:*:var %a = 1 | while ($hget(xdccv,%a).item) { var %name = $ifmatch | if (!$didwm($dname,27,$gettok(%name,1- $+ $calc($numtok(%name,95) -1),95),1)) did -a $dname 27 $gettok(%name,1- $+ $calc($numtok(%name,95) -1),95) | inc %a }
on *:dialog:xdccv:sclick:27:did -r $dname 28 | var %a = 1 | while ($hmatch(xdccv,$+($did($dname,27).seltext,_*),%a)) { did -a $dname 28 $right(00 $+ $gettok($ifmatch,$numtok($ifmatch,95),95),2) $+ . $hget(xdccv,$ifmatch) | inc %a }
on *:text:*:*:if ($xpack($1-)) addpacket $nick $ifmatch
on *:notice:*:*:if ($xpack($1-)) addpacket $nick $ifmatch

menu menubar {
  Visor &XDCC	:/dialog -md xdccv xdccv
}
menu channel {
  Visor &XDCC
  .Visor XDCC	:/dialog -md xdccv xdccv
  .Buscador XDCC	:/dialog -md xdccs xdccs
}

dialog xdccs {
  title "Buscador XDCC"
  size  -1 -1 525 370
  box "Búsqueda", 1, 5 10 515 8
  edit "", 2, 11 27 398 21,selected
  button "Buscar", 3, 429 25 75 25,default
  box "Resultados", 4, 5 52 515 8
  list 5, 5 67 515 265, size
  button "Aceptar", 6, 444 337 75 25, ok
}
on *:dialog:xdccs:dclick:5:ctcp $gettok($did($dname,5).seltext,1,32) xdcc send $gettok($did($dname,5).seltext,2,58) | if ($network == Dalnet) dccallow $+(+,$gettok($did($dname,5).seltext,1,32))
on *:dialog:xdccs:sclick:3:{
  did -r $dname 5
  var %a = 1
  while ($hget(xdccv,%a).item) {
    var %item = $ifmatch,%value = $hget(xdccv,%item),%pack = $gettok(%item,$numtok(%item,95),95),%name = $gettok(%item,1- $+ $calc($numtok(%item,95) -1),95)
    if (* $+ $replace($did($dname,2),$chr(32),*) $+ * iswm %value) did -a $dname 5 %name : $chr(35) $+ %pack : %value
    inc %a
  }
}
alias xdccs if (!$dialog(xdccs)) dialog -m xdccs xdccs
%rec.uptime 18938

[variables]
n0=%rec.uptime 19208
Explorando: ./mrc

Vista previa de: XDCCViewer.mrc
